Mini Kabibi Habibi

// Copyright 2023 Adobe Systems Incorporated

vImageSize = 1460;
// Note - this is a special case, regular #defines such as Macintosh or WIN_32 are not available here

#ifdef MacEve
previewWidth = 278;
previewHeight = 278;
linkGap = 4;
#endif

#ifdef WinEve
previewWidth = 260;
previewHeight = 260;
linkGap = 0;
#endif

size_width = max(zstring_width(zstring: '$$$/Dialog/ImageSize/Width=&Width:'), zstring_width(zstring: '$$$/Dialog/ImageSize/Height=&Height:'));
siz0_width = max(size_width, zstring_width(zstring: '$$$/Dialog/ImageSize/Resolution=&Resolution:'));
size_margin_width = gMarginWidth + (siz0_width - size_width);
sliderWidth = 120;
sliderEditTextWidth = 4 * max_char_width();
samplingPopupWidth = sliderWidth + sliderEditTextWidth;
dialog(name: '$$$/Dialog/ImageSize/Title=Image Size', class_name: 'TImageSizeDialog', target_id: 'col0', placement: place_row, isResizeable: true, resize_size_vertical: sizeRelSuperView, resize_size_horizontal: sizeRelSuperView, child_horizontal: align_left) {
    group(child_horizontal: align_fill, vertical: align_fill, resize_size_vertical: sizeRelSuperView, resize_location_vertical: locationFixed, resize_location_horizontal: locationRelSuperView, margin_left: 16 + linkGap) {
        group(view_id: 'rout', child_horizontal: align_fill) {
            group(horizontal: align_fill, placement: place_row, height: gEditTextHeight) {
                static_text(horizontal: align_right, name: '$$$/Dialog/ImageSize/ImageSizeLabel=Image Size:');
                static_text(view_id: 'fsiz', width: 12 * max_char_width());
                view(view_id: 'bpop', class_name: 'TPresetPopout', width: gPaletteIconWidth, height: gPaletteIconHeight, placement: place_row, horizontal: align_right, tooltip: '$$$/Dialog/ImageSize/ToolTip/OptionSettings=Set additional Image Size options');
            }
            control(view_id: 'rcoU', placement: place_row) {
                static_text(horizontal: align_right, class_name: 'TStaticText', name: '$$$/Dialog/ImageSize/Dimensions=Dimensions:');
                view(class_name: 'TUnitsPopup', view_id: 'mode', width: gSmallButtonHeight - 5, height: gSmallButtonHeight - 5, tooltip: '$$$/Dialog/ImageSize/ToolTip/ReadoutUnits=Select the dimensions display unit');
                static_text(view_id: 'rdim', class_name: 'TStaticText', width: 13 * max_char_width());
            }
            zpopup(view_id: 'fitp', resource_id: 559, horizontal: align_fill, tooltip: '$$$/Dialog/ImageSize/ToolTip/FitTo=Select the image size to fit to');
        }
        group(horizontal: align_fill, child_horizontal: align_fill) {
            group(view_id: 'clU0', class_name: 'TImageSizeUnit', placement: place_row, tooltip: '$$$/Dialog/ImageSize/ToolTip/SetWidth=Set the document width', enabled: true) {
                edit_text(view_id: 'col0', class_name: 'TFixedPoint', width: 5 * max_char_width(), name: '$$$/Dialog/ImageSize/Width3=Wi&dth:');
                popup(view_id: 'pco0', resource_id: 1016, horizontal: align_fill, tooltip: '$$$/Dialog/ImageSize/ToolTip/Units=Press the Shift key to change units separately');
            }
            group(view_id: 'rwU0', class_name: 'TImageSizeUnit', placement: place_row, tooltip: '$$$/Dialog/ImageSize/ToolTip/SetHeight=Set the document height', enabled: true) {
                edit_text(view_id: 'row0', class_name: 'TFixedPoint', width: 5 * max_char_width(), name: '$$$/Dialog/ImageSize/Height3=Hei&ght:');
                popup(view_id: 'pro0', resource_id: 1017, horizontal: align_fill, tooltip: '$$$/Dialog/ImageSize/ToolTip/Units=Press the Shift key to change units separately');
            }
            group(view_id: 'rsU0', class_name: 'TImageResUnit', placement: place_row, tooltip: '$$$/Dialog/ImageSize/ToolTip/Resolution=Set the document resolution', enabled: true) {
                edit_text(view_id: 'res0', class_name: 'TFixedPoint', width: 5 * max_char_width(), name: '$$$/Dialog/ImageSize/Resolution=&Resolution:');
                popup(view_id: 'pre0', resource_id: 1002, horizontal: align_fill);
            }
            group(placement: place_row, spacing: 4) {
                check_box(view_id: 'rscb', horizontal: align_right, margin_right: 0, name: '$$$/Dialog/ImageSize/ResampleCb=Re&sample:', tooltip: '$$$/Dialog/ImageSize/ToolTip/Resample=Interpolate the pixel information');
                popup(view_id: 'intp', resource_id: vImageSize, width: samplingPopupWidth, horizontal: align_fill, tooltip: '$$$/Dialog/ImageSize/ToolTip/InterpolationMethod=Set the interpolation method');
            }
            group(placement: place_row, class_name: 'TEditSlider', view_id: 'shad', spacing: 2, tooltip: '$$$/Dialog/ImageSize/ToolTip/ReduceNoise=Enter the amount of noise reduction') {
                static_text(view_id: 'slab', name: '$$$/Dialog/ImageSize/ReduceNoise=Reduce Noise:', horizontal: align_right, class_name: 'THotText');
                slider(view_id: 'ssld', height: 12, width: sliderWidth, horizontal: align_fill);
                edit_text(view_id: 'stxt', width: sliderEditTextWidth, class_name: 'TFixedPoint');
                static_text(name: '$$$/ControlsStrings/Percent=%');
            }
            group(placement: place_column, spacing: 4, include_view: showUpscaleUI) {
                static_text(horizontal: align_left, name: '$$$/Dialog/ImageSize/UpscaleText=Create a new, larger document with more detail');
                static_text(horizontal: align_left, view_id: 'txus', name: '$$$/Dialog/ImageSize/UpscaleLink=Open in Generative Upscale...');
            }
        }
// Note - this is a special case, regular #defines such as Macintosh or WIN_32 are not available here

#ifdef MacEve
        group(placement: place_row, vertical: align_bottom, resize_location_vertical: locationRelSuperView, reverse: true, name: 'OKCancel', show: true) {
#endif

#ifdef WinEve
        group(placement: place_row, vertical: align_bottom, resize_location_vertical: locationRelSuperView, name: 'OKCancel', show: true) {
#endif

            button(name: gOKString, horizontal: align_fill, view_id: 'ok  ', show: true, dismiss: true,
                default: true);
            button(name: gCancelString, horizontal: align_fill, view_id: 'cncl', show: true, dismiss: true);
        }
    }
    group(spacing: gLargeSpace, child_horizontal: align_fill, margin_right: 5, resize_size_horizontal: sizeRelSuperView, resize_size_vertical: sizeRelSuperView) {
        view(vertical: align_top, view_id: 'adpc', class_name: 'TAltDocPreviewCluster', child_horizontal: align_fill, forceOriginalUIColors: true, resize_size_horizontal: sizeRelSuperView, resize_size_vertical: sizeRelSuperView, spacing: gGap) {
            view(view_id: 'bgnd', class_name: 'TAltDocPreviewBackground', resize_size_horizontal: sizeRelSuperView, resize_size_vertical: sizeRelSuperView, width: previewWidth, height: previewHeight);
        }
    }
}
// Footer - Copyright 2023 Adobe Systems Incorporated