Mini Kabibi Habibi

layout toolsPalette
    {
    constant:
        kGroupMargin            : 1;
        kColumnSpacing          : -1;
        kToolSpacing            : -1;
        kToolSlotOutset         : 1;
        kFBMarginWidth          : 2;
        kMajorGroupSpacing      : 1;
        kMajorGroupMarginHeight : 3;
        zMaskModeToolTip        : '$$$/ToolsPalette/Tooltip/MaskModeCluster=Quick Mask Modes (Q)';
        zScreenModeToolTip		: '$$$/ToolsPalette/Tooltip/ScreenModeCluster=Screen Modes (F)';
        zImportImageToolTip		: '$$$/ToolsPalette/Tooltip/ImportImageCluster=Import Image ';
		zPlaygroundToolTip		: '$$$/ToolsPalette/Tooltip/PlaygroundCluster=Switch to Design Space';
        zGenerateImageToolTip   : '$$$/ToolsPalette/Tooltip/GenerateImage=Generate an image using a text prompt';

    interface:
        /* These are set by InstallToolbar */
        showFGBG : true;
        showQuickMaskMode : true;
        showGenerateImage : false;
        showImportImage : false;
        showScreenMode : true;
		vStdToolHeight : 26;
		vStdToolWidth : 33;

		vFBBKGLargeWidth : 70;
		vFBBKGLargeHeight : 48;
		vFBBKGSmallWidth : 32;
		vFBBKGSmallHeight : 48;

        fgbgMode : @small;
        showFGBGSmall <== showFGBG && fgbgMode == @small;
        showFGBGLarge <== showFGBG && fgbgMode != @small;
        showModeCluster <== showQuickMaskMode || showScreenMode;

    view TToolsPalette(
        placement   : place_column,
        margin      : 2,
        qDebugDraw  : false,
        spacing     : gGap)
        {
        TFixedGrid(identifier: @toolSlotGrid, horizontal: align_fill);

        TOptional(bind: @showFGBGSmall)
            {
            TFBBackground(
                identifier  : 'back',
                frame       : gIconButtonOtherButtonFrame,
				width		: vFBBKGSmallWidth,
				height		: vFBBKGSmallHeight);
            }

        TOptional(bind: @showFGBGLarge)
            {
            TFBBackgroundLarge(
                identifier  : 'bckL',
                frame       : gIconButtonOtherButtonFrame,
				width		: vFBBKGLargeWidth,
				height		: vFBBKGLargeHeight);
            }

        TOptional(
            bind: @showModeCluster,
            spacing: 0,
            identifier: @modeUberCluster)
            {
            TOptional(bind: @showQuickMaskMode)
                {
                TMaskModeCluster(
                    identifier  : 'msk!',
                    tooltip     : zMaskModeToolTip,
                    height      : vStdToolHeight,
                    width       : vStdToolWidth);
                }

            TOptional(bind: @showScreenMode)
                {
                TScreenModeCluster(
                    identifier  : 'scrn',
                    tooltip     : zScreenModeToolTip,
                    height      : vStdToolHeight,
                    width       : vStdToolWidth);
                }
            }

        TOptional(bind: @showImportImage)
            {
            TImportImageCluster(
                identifier  : 'imim',
                tooltip     : zImportImageToolTip,
                height      : vStdToolHeight,
                width       : vStdToolWidth);
            }

        TOptional(bind: @showGenerateImage)
            {
            TGenerateImageToolbarSlot(
                identifier  : 'giMb',
                tooltip     : zGenerateImageToolTip,
                richtooltip : true,
                height      : vStdToolHeight,
                width       : vStdToolWidth);
            }
        }
    }